ラジオペンチ

// ATmega328Pを使ってパルス幅を測定 20220514_PulseWidthMeasure
// D8に信号を入力 Timer1 インプットキャプチャで測定。オーバーフローのミスカウントをソフトで対策
// 2022/05/15 ラジオペンチ http://radiopench.blog96.fc2.com/

volatile int       irqFlag  = 0;           // タイマー1インプットキャプチャ割り込みフラグ
volatile uint16_t  ovfCount = 0;           //         オーバーフローカウンタ
volatile boolean execRising = true;        // 波形測定方向フラグ
volatile uint16_t t1, t2, t3;
volatile uint16_t t2MSB, t3MSB;

void setup() {
  Serial.begin(115200);

//  タイマー1をインプットキャプチャに設定
// （参照：http://igarage.cocolog-nifty.com/blog/2020/08/post-ba853b.html）
    TIMSK1 = 0b00100001;
    //           |  ||+---  TOIE1 オーバーフロー割込on
    //           |  |+----  OCIE1A
    //           |  +-----  OCIE1B
    //           +--------  ICIE1 キャプチャー割込on
    TCCR1A = 0b00000000;
    //         ||||  ++---  WGM 標準動作
    //         ||++-------  COM1B
    //         ++---------  COM1A
    TCCR1B = 0b00000001;
    //         || ||+++---  CS 16MHz入力(下位3ビットでプリスケーラー設定)    
    //         || ++------  WGM
    //         |+---------  ICES1 ICP1入力↓エッジ（プログラム内で動的に変更）    
    //         |----------  ICNC1 ノイズキャンセルなし
  startUp();
}

void loop() {
  uint32_t  tw, tp;           // クロック数で表したパルス幅、周期
  uint32_t last_tw, last_tp;
  float     t_tw, t_tp;       // パルス幅、周期
  while (irqFlag == 0) {      // IRQフラグが立つまで待つ
  }
  irqFlag = 0;

  tw = ((uint32_t)t2MSB << 16) + (uint32_t)t2 - (uint32_t)t1; // パルス幅の計算
  tp = ((uint32_t)t3MSB << 16) + (uint32_t)t3 - (uint32_t)t1; // パルス周期の計算

  if((tw - last_tw) > 30000) tw -= 65536;  // TC1オーバーフローミスカウント対策の暫定対策
  if((last_tw - tw) > 30000) tw += 65536;
  if((tp - last_tp) > 30000) tp -= 65536;
  if((last_tp - tp) > 30000) tp += 65536;
  
  t_tw = tw * 62.5E-9;
  t_tp = tp * 62.5E-9;
  Serial.print(t_tw, 9); Serial.print(", "); Serial.print(t_tp, 9);
  Serial.println();
  t1 = t3;              // 次回の測定のためにパルスの先頭位置を記録
  last_tw = tw;
  last_tp = tp;
}

void startUp() {
  Serial.println();
  Serial.println("Pulse measurement start");
  Serial.println("width, period");
  for (int i = 0; i < 3; i++) {      // 変数が落ち着くまで空廻し
    while (irqFlag == 0) {           // IRQフラグが立つまで待つ
    }
    irqFlag = 0;
    t1 = t3;
  }
}

ISR(TIMER1_OVF_vect) {      // Timer1オーバーフロー割り込み処理
  ovfCount ++;
}

ISR(TIMER1_CAPT_vect) {      // Timer1 インプットキャプチャ割り込み処理
  uint16_t t;
//  sei();                     // 途中でovfCountの値が動くと困るので割り込み禁止で処理（これは逆効果）
  t = ICR1;
  if (execRising == true) {  // 立ち上がりの処理だったら、
    t3 = t;                  // パルス周期測定のための立ち上がり時刻として記録
    t3MSB = ovfCount;
    ovfCount = 0;            // オーバーフローカウンタをクリア
    TCCR1B &= 0b10111111;    // 次回はネガエッジでキャプチャ(ICES1=0)
    execRising = false;      // 次回は立下りの処理
    irqFlag = 1;             // フラグセットしてメインに通知
  } else {                   // 立ち下がりの処理だったら
    t2 = t;                  // 立下り時刻として記録
    t2MSB = ovfCount;
    TCCR1B |= 0b01000000;    // 次回はポジエッジでキャプチャ(ICES1=1)
    execRising = true;       // 次回は立ち上がりの処理
  }
//  cli();
}